WinPE2_CD.CMDのコマンド解説

（チェックボックスにチェックを入れると解説が表示される）

set WinPEDir=%~dp0winpe_x86

%~dp0は、このバッチファイルの存在するディレクトリのパスをあらわす。（末尾に\が付き、""で囲まない）
その直下にwinpe_x86というサブフォルダを作ると仮定した時、そのフルパスをWinPEDirという変数に収めろという意味。

if exist %WinPEDir%\nul rd /s /q %WinPEDir%

もしもWinPEDirというフォルダが既に存在していたら削除しろという意味。
これはこの直後に呼び出すcopype.cmdにおいて、WinPEDirフォルダが事前に存在していると失敗してしまうため、それを防ぐ予防策である。確認せずに削除するので大事なファイルなどをWinPEDirフォルダ内に置いておかないように注意すること。

imagex /apply %WinPEDir%\winpe.wim 1 %WinPEDir%\mount

copype.cmdによってWinPEDirフォルダに作製されたwinpe.wimの中身を、imagex.exeでmountフォルダに展開する。

copy %WinPEDir%\ISO\bootmgr %WinPEDir%\mount
mkdir %WinPEDir%\mount\boot
xcopy /cherky %WinPEDir%\ISO\boot %WinPEDir%\mount\boot\

ISOフォルダのbootmgrとbootフォルダを丸ごとmountフォルダにコピーする。

Bcdedit /createstore %WinPEDir%\mount\boot\BCD
Bcdedit /store %WinPEDir%\mount\boot\BCD -create {bootmgr} /d "Boot Manager"
Bcdedit /store %WinPEDir%\mount\boot\BCD -set {bootmgr} device boot
for /f "tokens=2 delims={}" %%i in ('Bcdedit /store %WinPEDir%\mount\boot\BCD -create /d "WINPE" -application osloader') do set BCDGUID={%%i}
Bcdedit /store %WinPEDir%\mount\boot\BCD -set %BCDGUID% osdevice boot
Bcdedit /store %WinPEDir%\mount\boot\BCD -set %BCDGUID% device boot
Bcdedit /store %WinPEDir%\mount\boot\BCD -set %BCDGUID% path \windows\system32\winload.exe
Bcdedit /store %WinPEDir%\mount\boot\BCD -set %BCDGUID% systemroot \windows
Bcdedit /store %WinPEDir%\mount\boot\BCD -set %BCDGUID% winpe yes
Bcdedit /store %WinPEDir%\mount\boot\BCD -set %BCDGUID% detecthal yes
Bcdedit /store %WinPEDir%\mount\boot\BCD -displayorder %BCDGUID% -addlast

bcdedit.exeを使って、新しいBCDを作る一連の処置

copy C:\Program Files\Windows AIK\Tools\x86\imagex.exe %WinPEDir%\mount\Windows\System32\

WindowsAIKが持つimagex.exeはバックアップやHDDの交換時などに役立つアプリケーションなので、WinPEに取り込むために、mountフォルダ下のサブフォルダにコピーしておく。

peimg /prep /f %WinPEDir%\mount\Windows

peimage /prefを行うと、対象フォルダの最適化が行われ無駄なものが削ぎ落とされる。ただしその後、対象フォルダ内をカスタマイズできなくなるので、必要なカスタマイズが全て完了してから行わなければならない。

oscdimg -n -m -o -b%WinPEDir%\etfsboot.com %WinPEDir%\mount %WinPEDir%\WinPE2_CD.iso

oscdimgによって、mountフォルダの中身が、ISOファイルに変換される。ブート用のファイルとしてetfsboot.comが指定されている。